Giải thuật và lập trình: §12. Bài toán tìm bộ ghép cực đại với trọng số cực tiểu trên đồ thị hai phía. Thuật toán Hungari
12.1. Bài toán phân công
Đây là một dạng bài toán phát biểu như sau: Có m người (đánh số 1, 2, ..., m) và n công việc (đánh số 1, 2, ..., n), mỗi người có khả năng thực hiện một số công việc nào đó. Để giao cho người i thực hiện công việc j cần một chi phí là c[i, j] ≥ 0. Cần phân cho mỗi thợ một việc và mỗi việc chỉ do một thợ thực hiện sao cho số công việc có thể thực hiện được là nhiều nhất và nếu có ≥ 2 phương án đều thực hiện được nhiều công việc nhất thì chỉ ra phương án chi phí ít nhất.
Dựng đồ thị hai phía G = (X∪Y, E) với X là tập m người, Y là tập n việc và (u, v) ∈ E với trọng số c[u, v] nếu như người u làm được công việc v. Bài toán đưa về tìm bộ ghép nhiều cạnh nhất của G có trọng số nhỏ nhất.
Gọi k = max(m, n). Bổ sung vào tập X và Y một số đỉnh giả để ⏐X⏐=⏐Y⏐= k.
Gọi M là một số dương đủ lớn hơn chi phí của mọi phép phân công có thể. Với mỗi cặp đỉnh (u, v): u ∈ X và v ∈ Y. Nếu (u, v) ∉ E thì ta bổ sung cạnh (u, v) vào E với trọng số là M.
Khi đó ta được G là một đồ thị hai phía đầy đủ (Đồ thị hai phía mà giữa một đỉnh bất kỳ của X và một đỉnh bất kỳ của Y đều có cạnh nối). Và nếu như ta tìm được bộ ghép đầy đủ k cạnh mang trọng số nhỏ nhất thì ta chỉ cần loại bỏ khỏi bộ ghép đó những cạnh mang trọng số M vừa thêm vào thì sẽ được kế hoạch phân công 1 người ↔ 1 việc cần tìm. Điều này dễ hiểu bởi bộ ghép đầy đủ mang trọng số nhỏ nhất tức là phải ít cạnh trọng số M nhất, tức là số phép phân công là nhiều nhất, và tất nhiên trong số các phương án ghép ít cạnh trọng số M nhất thì đây là phương án trọng số nhỏ nhất, tức là tổng chi phí trên các phép phân công là ít nhất.
12.2. Phân tích
Vào: Đồ thị hai phía đầy đủ G = (X∪Y, E); ⏐X⏐=⏐Y⏐= k. Được cho bởi ma trận vuông C cỡ kxk, c[i, j] = trọng số cạnh nối đỉnh Xi với Yj. Giả thiết c[i, j] ≥ 0. với mọi i, j.
Ra: Bộ ghép đầy đủ trọng số nhỏ nhất.
Hai định lý sau đây tuy rất đơn giản nhưng là những định lý quan trọng tạo cơ sở cho thuật toán sẽ trình bày:
Định lý 1: Loại bỏ khỏi G những cạnh trọng số > 0. Nếu những cạnh trọng số 0 còn lại tạo ra bộ ghép k cạnh trong G thì đây là bộ ghép cần tìm.
Chứng minh: Theo giả thiết, các cạnh của G mang trọng số không âm nên bất kỳ bộ ghép nào trong G cũng có trọng số không âm, mà bộ ghép ở trên mang trọng số 0, nên tất nhiên đó là bộ ghép đầy đủ trọng số nhỏ nhất.
Định lý 2: Với đỉnh Xi, nếu ta cộng thêm một số ∆(dương hay âm) vào tất cả những cạnh liên thuộc với Xi (tương đương với việc cộng thêm ∆ vào tất cả các phần tử thuộc hàng i của ma trận C) thì không ảnh hưởng tới bộ ghép đầy đủ trọng số nhỏ nhất.
Chứng minh: Với một bộ ghép đầy đủ bất kỳ thì có một và chỉ một cạnh ghép với X[i]. Nên việc cộng thêm ∆ vào tất cả các cạnh liên thuộc với X[i] sẽ làm tăng trọng số bộ ghép đó lên ∆. Vì vậy nếu như ban đầu, M là bộ ghép đầy đủ trọng số nhỏ nhất thì sau thao tác trên, M vẫn là bộ ghép đầy đủ trọng số nhỏ nhất.
Hệ quả: Với đỉnh Y[j], nếu ta cộng thêm một số ∆ (dương hay âm) vào tất cả những cạnh liên thuộc với Y[j] (tương đương với việc cộng thêm ∆ vào tất cả các phần tử thuộc cột j của ma trận C) thì không ảnh hưởng tới bộ ghép đầy đủ trọng số nhỏ nhất.
Từ đây có thể nhận ra tư tưởng của thuật toán: Từ đồ thị G, ta tìm chiến lược cộng/trừ một cách hợp lý trọng số của các cạnh liên thuộc với một đỉnh nào đó để được một đồ thị mới vẫn có các cạnh trọng số không âm, mà các cạnh trọng số 0 của đồ thị mới đó chứa một bộ ghép đầy đủ k cạnh.
Ví dụ: Biến đổi ma trận trọng số của đồ thị hai phía 3 đỉnh trái, 3 đỉnh phải:
Phép xoay trọng số cạnh
12.3. Thuật toán
12.3.1. Các khái niệm:
Để cho gọn, ta gọi những cạnh trọng số 0 của G là những 0_cạnh.
Xét một bộ ghép M chỉ gồm những 0_cạnh.
Những đỉnh ∈ M gọi là những đỉnh đã ghép, những đỉnh còn lại gọi là những đỉnh chưa ghép.
Những 0_cạnh ∈ M gọi là những 0_cạnh đã ghép, những 0_cạnh còn lại là những 0_cạnh chưa ghép.
Nếu ta định hướng lại các 0_cạnh như sau: Những 0_cạnh chưa ghép cho hướng từ tập X sang tập Y, những 0_cạnh đã ghép cho hướng từ tập Y về tập X. Khi đó:
Đường pha (Alternating Path) là một đường đi cơ bản xuất phát từ một X_đỉnh chưa ghép đi theo các 0_cạnh đã định hướng ở trên. Như vậy dọc trên đường pha, các 0_cạnh chưa ghép và những 0_cạnh đã ghép xen kẽ nhau. Vì đường pha chỉ là đường đi cơ bản trên đồ thị định hướng nên việc xác định những đỉnh nào có thể đến được từ x ∈ X bằng một đường pha có thể sử dụng các thuật toán tìm kiếm trên đồ thị (BFS hoặc DFS). Những đỉnh và những cạnh được duyệt qua tạo thành một cây pha gốc x.
Một đường mở (Augmenting Path) là một đường pha đi từ một X_đỉnh chưa ghép tới một Y_đỉnh chưa ghép. Như vậy:
Đường đi trực tiếp từ một X_đỉnh chưa ghép tới một Y_đỉnh chưa ghép qua một 0_cạnh chưa ghép cũng là một đường mở.
Dọc trên đường mở, số 0_cạnh chưa ghép nhiều hơn số 0_cạnh đã ghép đúng 1 cạnh.
12.3.2. Thuật toán Hungari
Bước 1: Khởi tạo:
Một bộ ghép M := ∅
Bước 2: Với mọi đỉnh x* ∈X, ta tìm cách ghép x* như sau.
Bắt đầu từ đỉnh x* chưa ghép, thử tìm đường mở bắt đầu ở x* bằng thuật toán tìm kiếm trên đồ thị (BFS hoặc DFS - thông thường nên dùng BFS để tìm đường qua ít cạnh nhất) có hai khả năng xảy ra:
Hoặc tìm được đường mở thì dọc theo đường mở, ta loại bỏ những cạnh đã ghép khỏi M và thêm vào M những cạnh chưa ghép, ta được một bộ ghép mới nhiều hơn bộ ghép cũ 1 cạnh và đỉnh x* trở thành đã ghép.
Hoặc không tìm được đường mở thì do ta sử dụng thuật toán tìm kiếm trên đồ thị nên có thể xác định được hai tập:
VisitedX = {Tập những X_đỉnh có thể đến được từ x* bằng một đường pha}
VisitedY = {Tập những Y_đỉnh có thể đến được từ x* bằng một đường pha}
Gọi ∆ là trọng số nhỏ nhất của các cạnh nối giữa một đỉnh thuộc VisitedX với một đỉnh không thuộc VisitedY. Dễ thấy ∆ > 0 bởi nếu ∆ = 0 thì tồn tại một 0_cạnh (x, y) với x∈VisitedX và y∉VisitedY. Vì x* đến được x bằng một đường pha và (x, y) là một 0_cạnh nên x* cũng đến được y bằng một đường pha, dẫn tới y ∈ VisitedY, điều này vô lý.
Biến đổi đồ thị G như sau: Với ∀x ∈ VisitedX, trừ ∆ vào trọng số những cạnh liên thuộc với x, Với ∀ y ∈ VisitedY, cộng ∆ vào trọng số những cạnh liên thuộc với y.
Lặp lại thủ tục tìm kiếm trên đồ thị thử tìm đường mở xuất phát ở x* cho tới khi tìm ra đường mở.
Bước 3: Sau bước 2 thì mọi X_đỉnh đều được ghép, in kết quả về bộ ghép tìm được.
Mô hình cài đặt của thuật toán có thể viết như sau:
<Khởi tạo: M := ∅ ...>; for (x*∈X) do begin repeat <Tìm đường mở xuất phát ở x*>; if <Không tìm thấy đường mở> then <Biến đổi đồ thị G: Chọn ∆ := ...>; until <Tìm thấy đường mở>; <Dọc theo đường mở, loại bỏ những cạnh đã ghép khỏi M và thêm vào M những cạnh chưa ghép>; end; <Kết quả>;
Ví dụ minh hoạ:
Để không bị rối hình, ta hiểu những cạnh không ghi trọng số là những 0_cạnh, những cạnh không vẽ mang trọng số rất lớn trong trường hợp này không cần thiết phải tính đến. Những cạnh nét đậm là những cạnh đã ghép, những cạnh nét thanh là những cạnh chưa ghép.
Thuật toán Hungari
Để ý rằng nếu như không tìm thấy đường mở xuất phát ở x* thì quá trình tìm kiếm trên đồ thị sẽ cho ta một cây pha gốc x*. Giá trị xoay ∆ thực chất là trọng số nhỏ nhất của cạnh nối một X_đỉnh trong cây pha với một Y_đỉnh ngoài cây pha (cạnh ngoài). Việc trừ ∆ vào những cạnh liên thuộc với X_đỉnh trong cây pha và cộng ∆ vào những cạnh liên thuộc với Y_đỉnh trong cây pha sẽ làm cho cạnh ngoài nói trên trở thành 0_cạnh, các cạnh khác vẫn có trọng số ≥ 0. Nhưng quan trọng hơn là tất cả những cạnh trong cây pha vẫn cứ là 0_cạnh. Điều đó đảm bảo cho quá trình tìm kiếm trên đồ thị lần sau sẽ xây dựng được cây pha mới lớn hơn cây pha cũ (Thể hiện ở chỗ: tập VisitedY sẽ rộng hơn trước ít nhất 1 phần tử). Vì tập các Y_ đỉnh đã ghép là hữu hạn nên sau không quá k bước, sẽ có một Y_đỉnh chưa ghép ∈ VisitedY, tức là tìm ra đường mở.
Trên thực tế, để chương trình hoạt động nhanh hơn, trong bước khởi tạo, người ta có thể thêm một thao tác:
Với mỗi đỉnh x ∈ X, xác định trọng số nhỏ nhất của các cạnh liên thuộc với x, sau đó trừ tất cả trọng số các cạnh liên thuộc với x đi trọng số nhỏ nhất đó. Làm tương tự như vậy với các Y_đỉnh.
Điều này tương đương với việc trừ tất cả các phần tử trên mỗi hàng của ma trận C đi giá trị nhỏ nhất trên hàng đó, rồi lại trừ tất cả các phần tử trên mỗi cột của ma trận C đi phần tử nhỏ nhất trên cột đó. Khi đó số 0_cạnh của đồ thị là khá nhiều, có thể chứa ngay bộ ghép đầy đủ hoặc chỉ cần qua ít bước biến đổi là sẽ chứa bộ ghép đầy đủ k cạnh.
Để tưởng nhớ hai nhà toán học König và Egervary, những người đã đặt cơ sở lý thuyết đầu tiên cho phương pháp, người ta đã lấy tên của đất nước sinh ra hai nhà toán học này để đặt tên cho thuật toán.
Mặc dù sau này có một số cải tiến nhưng tên gọi Thuật toán Hungari (Hungarian Algorithm) vẫn được dùng phổ biến.
12.4. CÀI ĐẶT
12.4.1. Phương pháp đối ngẫu Kuhn-Munkres (Không làm biến đổi ma trận C ban đầu)
Phương pháp Kuhn-Munkres đi tìm hai dãy số Fx[1..k] và Fy[1..k] thoả mãn:
c[i, j] - Fx[i] - Fy[j] ≥ 0
Tập các cạnh (X[i], Y[j]) thoả mãn c[i, j] - Fx[i] - Fy[j] = 0 chứa trọn một bộ ghép đầy đủ k cạnh,đây chính là bộ ghép cần tìm.
Chứng minh:
Nếu tìm được hai dãy số thoả mãn trên thì ta chỉ việc thực hiện hai thao tác:
Với mỗi đỉnh X[i], trừ tất cả trọng số của những cạnh liên thuộc với X[i] đi Fx[i]
Với mỗi đỉnh Y[j], trừ tất cả trọng số của những cạnh liên thuộc với Y[j] đi Fy[j]
(Hai thao tác này tương đương với việc trừ tất cả trọng số của các cạnh (X[i], Y[j]) đi một lượng Fx[i] + Fy[j] tức là c[i, j] := c[i, j] - Fx[i] - Fy[j])
Thì dễ thấy đồ thị mới tạo thành sẽ gồm có các cạnh trọng số không âm và những 0_cạnh của đồ thị chứa trọn một bộ ghép đầy đủ.
(Có nhiều phương án khác: Fx = (0, 0, 1, 1); Fy = (0, 0, -1, 2) cũng đúng)
Vậy phương pháp Kuhn-Munkres đưa việc biến đổi đồ thị G (biến đổi ma trận C) về việc biến đổi hay dãy số Fx và Fy. Việc trừ ∆ vào trọng số tất cả những cạnh liên thuộc với X[i] tương đương với việc tăng Fx[i] lên ∆. Việc cộng ∆ vào trọng số tất cả những cạnh liên thuộc với Y[j] tương đương với giảm Fy[j] đi ∆. Khi cần biết trọng số cạnh (X[i], Y[j]) là bao nhiêu sau các bước biến đổi, thay vì viết c[i, j], ta viết c[i, j] - Fx[i] - Fy[j].
Ví dụ: Thủ tục tìm đường mở trong thuật toán Hungari đòi hỏi phải xác định được cạnh nào là 0_cạnh, khi cài đặt bằng phương pháp Kuhn-Munkres, việc xác định cạnh nào là 0_cạnh có thể kiểm tra bằng đẳng thức: c[i, j] - Fx[i] - Fy[j] = 0 hay c[i, j] = Fx[i] + Fy[j].
Sơ đồ cài đặt phương pháp Kuhn-Munkres có thể viết như sau:
Bước 1: Khởi tạo:
M := ∅;
Việc khởi tạo các Fx, Fy có thể có nhiều cách chẳng hạn Fx[i] := 0; Fy[j] := 0 với ∀i, j.
Hoặc: Fx[i] := 
Bước 2: Với mọi đỉnh x*∈X, ta tìm cách ghép x* như sau:
Bắt đầu từ đỉnh x* , thử tìm đường mở bắt đầu ở x* bằng thuật toán tìm kiếm trên đồ thị (BFS hoặc DFS). Lưu ý rằng 0_cạnh là cạnh thoả mãn c[i, j] = Fx[i] + Fy[j]. Có hai khả năng xảy ra:
Hoặc tìm được đường mở thì dọc theo đường mở, ta loại bỏ những cạnh đã ghép khỏi M và thêm vào M những cạnh chưa ghép.
Hoặc không tìm được đường mở thì xác định được hai tập:
VisitedX = {Tập những X_đỉnh có thể đến được từ x* bằng một đường pha}
- VisitedY = {Tập những Y_đỉnh có thể đến được từ x* bằng một đường pha}
- Đặt ∆ := min{c[i, j] - Fx[i] - Fy[j] ⏐ ∀X[i] ∈ VisitedX; ∀Y[j] ∉ VisitedY}
Với ∀X[i] ∈ VisitedX: Fx[i] := Fx[i] + ∆;
Với ∀Y[j] ∈ VisitedY: Fy[j] := Fy[j] - ∆;
Lặp lại thủ tục tìm đường mở xuất phát tại x* cho tới khi tìm ra đường mở.
Đáng lưu ý ở phương pháp Kuhn-Munkres là nó không làm thay đổi ma trận C ban đầu. Điều đó thực sự hữu ích trong trường hợp trọng số của cạnh (X[i], Y[j]) không được cho một cách tường minh bằng giá trị C[i, j] mà lại cho bằng hàm c(i, j): trong trường hợp này, việc trừ hàng/cộng cột trực tiếp trên ma trận chi phí C là không thể thực hiện được.
12.4.2. Cài đặt
a) Biểu diễn bộ ghép
Để biểu diễn bộ ghép, ta sử dụng hai mảng: matchX[1..k] và matchY[1..k].
matchX[i] là đỉnh thuộc tập Y ghép với đỉnh X[i]
matchY[j] là đỉnh thuộc tập X ghép với đỉnh Y[j].
Tức là nếu như cạnh (X[i], Y[j]) thuộc bộ ghép thì matchX[i] = j và matchY[j] = i.
Quy ước rằng:
Nếu như X[i] chưa ghép với đỉnh nào của tập Y thì matchX[i] = 0
Nếu như Y[j] chưa ghép với đỉnh nào của tập X thì matchY[j] = 0.
Để thêm một cạnh (X[i], Y[j]) vào bộ ghép thì chỉ việc đặt matchX[i] := j và matchY[j] := i;
Để loại một cạnh (X[i], Y[j]) khỏi bộ ghép thì chỉ việc đặt matchX[i] := 0 và matchY[j] := 0;
b) Tìm đường mở như thế nào
Ta sẽ tìm đường mở và xây dựng hai tập VisitedX và VisitedY bằng thuật toán tìm kiếm theo chiều rộng chỉ xét tới những đỉnh và những 0_cạnh đã định hướng như đã nói trong phần đầu:
Khởi tạo một hàng đợi (Queue) ban đầu chỉ có một đỉnh x*. Thuật toán tìm kiếm theo chiều rộng làm việc theo nguyên tắc lấy một đỉnh v khỏi Queue và lại đẩy Queue những nối từ v chưa được thăm. Như vậy nếu thăm tới một Y_đỉnh chưa ghép thì tức là ta tìm đường mở kết thúc ở Y_đỉnh chưa ghép đó, quá trình tìm kiếm dừng ngay. Còn nếu ta thăm tới một đỉnh y ∈ Y đã ghép, dựa vào sự kiện: từ y chỉ có thể tới được matchY[y] theo duy nhất một 0_cạnh định hướng, nên ta có thể đánh dấu thăm y, thăm luôn cả matchY[y], và đẩy vào Queue phần tử matchY[y] ∈ X.
Input: file văn bản ASSIGN.INP
• Dòng 1: Ghi hai số m, n theo thứ tự là số thợ và số việc cách nhau 1 dấu cách (m, n ≤ 100)
• Các dòng tiếp theo, mỗi dòng ghi ba số i, j, c[i, j] cách nhau 1 dấu cách thể hiện thợ i làm được việc j và chi phí để làm là c[i, j] (1 ≤ i ≤ m; 1 ≤ j ≤ n; 0 ≤ c[i, j] ≤ 100).
Output: file văn bản ASSIGN.OUT, mô tả phép phân công tối ưu tìm được.
P_4_12_1.PAS * Thuật toán Hungari program AssignmentProblemSolve; const InputFile = 'ASSIGN.INP'; OutputFile = 'ASSIGN.OUT'; max = 100; maxC = 10001; var c: array[1..max, 1..max] of Integer; Fx, Fy, matchX, matchY, Trace: array[1..max] of Integer; m, n, k, start, finish: Integer; {đường mở sẽ bắt đầu từ start∈X và kết thúc ở finish∈Y} procedure Enter; var i, j: Integer; f: Text; begin Assign(f, InputFile); Reset(f); ReadLn(f, m, n); if m > n then k := m else k := n; for i := 1 to k do for j := 1 to k do c[i, j] := maxC; while not SeekEof(f) do ReadLn(f, i, j, c[i, j]); Close(f); end; procedure Init; {Khởi tạo} var i, j: Integer; begin {Bộ ghép rỗng} FillChar(matchX, SizeOf(matchX), 0); FillChar(matchY, SizeOf(matchY), 0); {Fx[i] := Trọng số nhỏ nhất của các cạnh liên thuộc với X[i]} for i := 1 to k do begin Fx[i] := maxC; for j := 1 to k do if c[i, j] < Fx[i] then Fx[i] := c[i, j]; end; {Fy[j] := Trọng số nhỏ nhất của các cạnh liên thuộc với Y[j]} for j := 1 to k do begin Fy[j] := maxC; for i := 1 to k do {Lưu ý là trọng số cạnh (x[i], y[j]) bây giờ là c[i, j] - Fx[i] chứ không còn là c[i, j] nữa} if c[i, j] - Fx[i] < Fy[j] then Fy[j] := c[i, j] - Fx[i]; end; {Việc khởi tạo các Fx và Fy như thế này chỉ đơn giản là để cho số 0_cạnh trở nên càng nhiều càng tốt mà thôi} {Ta hoàn toàn có thể khởi gán các Fx và Fy bằng giá trị 0} end; {Hàm cho biết trọng số cạnh (X[i], Y[j]) } function GetC(i, j: Integer): Integer; begin GetC := c[i, j] - Fx[i] - Fy[j]; end; procedure FindAugmentingPath; {Tìm đường mở bắt đầu ở start} var Queue: array[1..max] of Integer; i, j, first, last: Integer; begin FillChar(Trace, SizeOf(Trace), 0); {Trace[j] = X_đỉnh liền trước Y[j] trên đường mở} {Thuật toán BFS} Queue[1] := start; {Đẩy start vào hàng đợi} first := 1; last := 1; repeat i := Queue[first]; Inc(first); {Lấy một đỉnh X[i] khỏi hàng đợi} for j := 1 to k do {Duyệt những Y_đỉnh chưa thăm kề với X[i] qua một 0_cạnh chưa ghép} if (Trace[j] = 0) and (GetC(i, j) = 0) then begin Trace[j] := i; {Lưu vết đường đi, cùng với việc đánh dấu (≠0) luôn} if matchY[j] = 0 then {Nếu j chưa ghép thì ghi nhận nơi kết thúc đường mở và thoát luôn} begin finish := j; Exit; end; Inc(last); Queue[last] := matchY[j]; {Đẩy luôn matchY[j] vào Queue} end; until first > last; {Hàng đợi rỗng} end; procedure SubX_AddY; {Xoay các trọng số cạnh} var i, j, t, Delta: Integer; VisitedX, VisitedY: set of Byte; begin (* Chú ý: VisitedY = {y | Trace[y] ≠ 0} VisitedX = {start} ∪ match(VisitedY) = {start} ∪ {matchY[y] | Trace[y] ≠ 0} *) VisitedX := [start]; VisitedY := []; for j := 1 to k do if Trace[j] <> 0 then begin Include(VisitedX, matchY[j]); Include(VisitedY, j); end; {Sau khi xác định được VisitedX và VisitedY, ta tìm ∆ là trọng số nhỏ nhất của cạnh nối từ VisitedX ra Y\VisitedY} Delta := maxC; for i := 1 to k do if i in VisitedX then for j := 1 to k do if not (j in VisitedY) and (GetC(i, j) < Delta) then Delta := GetC(i, j); {Xoay trọng số cạnh} for t := 1 to k do begin {Trừ trọng số những cạnh liên thuộc với VisitedX đi Delta} if t in VisitedX then Fx[t] := Fx[t] + Delta; {Cộng trọng số những cạnh liên thuộc với VisitedY lên Delta} if t in VisitedY then Fy[t] := Fy[t] - Delta; end; end; {Nới rộng bộ ghép bởi đường mở tìm được}procedure Enlarge; var x, next: Integer; begin repeat x := Trace[finish]; next := matchX[x]; matchX[x] := finish; matchY[finish] := x; finish := Next; until finish = 0; end; procedure Solve; {Thuật toán Hungari} var x, y: Integer; begin for x := 1 to k do begin start := x; finish := 0; {Khởi gán nơi xuất phát đường mở, finish = 0 nghĩa là chưa tìm thấy đường mở} repeat FindAugmentingPath; {Thử tìm đường mở} if finish = 0 then SubX_AddY; {Nếu không thấy thì xoay các trọng số cạnh và lặp lại} until finish <> 0; {Cho tới khi tìm thấy đường mở} Enlarge; {Tăng cặp dựa trên đường mở tìm được} end; end; procedure Result; var x, y, Count, W: Integer; f: Text; begin Assign(f, OutputFile); Rewrite(f); WriteLn(f, 'Optimal assignment:'); W := 0; Count := 0; for x := 1 to m do {In ra phép phân công thì chỉ cần xét đến m, không cần xét đến k} begin y := matchX[x]; {Những cạnh có trọng số maxC tương ứng với một thợ không được giao việc và một việc không được phân công} if c[x, y] < maxC then begin Inc(Count); WriteLn(f, Count:5, ') X[', x, '] - Y[', y, '] ', c[x, y]); W := W + c[x, y]; end; end; WriteLn(f, 'Cost: ', W); Close(f); end; begin Enter; Init; Solve; Result; end.
Nhận xét:
Nếu cài đặt như trên thì cho dù đồ thị có cạnh mang trọng số âm, chương trình vẫn tìm được bộ ghép cực đại với trọng số cực tiểu. Lý do: Ban đầu, ta trừ tất cả các phần tử trên mỗi hàng của ma trận C đi giá trị nhỏ nhất trên hàng đó, rồi lại trừ tất cả các phần tử trên mỗi cột của ma trận C đi giá trị nhỏ nhất trên cột đó (Phép trừ ở đây làm gián tiếp qua các Fx, Fy chứ không phải trừ trực tiếp trên ma trận C). Nên sau bước này, tất cả các cạnh của đồ thị sẽ có trọng số không âm bởi phần tử nhỏ nhất trên mỗi cột của C chắc chắn là 0.
Sau khi kết thúc thuật toán, tổng tất cả các phần tử ở hai dãy Fx, Fy bằng trọng số cực tiểu của bộ ghép đầy đủ tìm được trên đồ thị ban đầu.
Một vấn đề nữa phải hết sức cẩn thận trong việc ước lượng độ lớn của các phần tử Fx và Fy. Nếu như giả thiết cho các trọng số không quá 500 thì ta không thể dựa vào bất đẳng thức Fx(x) + Fy(y) ≤ c(x, y) mà khẳng định các phần tử trong Fx và Fy cũng ≤ 500. Hãy tự tìm ví dụ để hiểu rõ hơn bản chất thuật toán.
12.5. Bài toán tìm bộ ghép cực đại với trọng số cực đại trên đồ thị hai phía
Bài toán tìm bộ ghép cực đại với trọng số cực đại cũng có thể giải nhờ phương pháp Hungari bằng cách đổi dấu tất cả các phần tử ma trận chi phí (Nhờ nhận xét 1).
Khi cài đặt, ta có thể sửa lại đôi chút trong chương trình trên để giải bài toán tìm bộ ghép cực đại với trọng số cực đại mà không cần đổi dấu trọng số. Cụ thể như sau:
Bước 1: Khởi tạo:
M := ∅;
Khởi tạo hai dãy Fx và Fy thoả mãn: ∀i, j: Fx[i] + Fy[j] ≥ c[i, j]; Chẳng hạn ta có thể đặt Fx[i] := Phần tử lớn nhất trên dòng i của ma trận C và đặt các Fy[j] := 0.
Bước 2: Với mọi đỉnh x* ∈X, ta tìm cách ghép x* như sau:
Với cách hiểu 0_cạnh là cạnh thoả mãn c[i, j] = Fx[i] + Fy[j]. Bắt đầu từ đỉnh x* , thử tìm đường mở bắt đầu ở x*. Có hai khả năng xảy ra:
Hoặc tìm được đường mở thì dọc theo đường mở, ta loại bỏ những cạnh đã ghép khỏi M và thêm vào M những cạnh chưa ghép.
Hoặc không tìm được đường mở thì xác định được hai tập:
VisitedX = {Tập những X_đỉnh có thể đến được từ x* bằng một đường pha}
- VisitedY = {Tập những Y_đỉnh có thể đến được từ x* bằng một đường pha}
- Đặt ∆ := min{Fx[i] + Fy[j] - c[i, j] ⏐ ∀X[i] ∈ VisitedX; ∀Y[j] ∉ VisitedY}
Với ∀X[i] ∈ VisitedX: Fx[i] := Fx[i] - ∆;
Với ∀Y[j] ∈ VisitedY: Fy[j] := Fy[j] + ∆;
Lặp lại thủ tục tìm đường mở xuất phát tại x* cho tới khi tìm ra đường mở.
Bước 3: Sau bước 2 thì mọi X_đỉnh đều đã ghép, ta được một bộ ghép đầy đủ k cạnh với trọng số lớn nhất.
Dễ dàng chứng minh được tính đúng đắn của phương pháp, bởi nếu ta đặt: c'[i, j] = - c[i, j]; F'x[i] := - Fx[i]; F'y[j] = - Fy[j].
Thì bài toán trở thành tìm cặp ghép đầy đủ trọng số cực tiểu trên đồ thị hai phía với ma trận trọng số c'[1..k, 1..k]. Bài toán này được giải quyết bằng cách tính hai dãy đối ngẫu F'x và F'y. Từ đó bằng những biến đổi đại số cơ bản, ta có thể kiểm chứng được tính tương đương giữa các bước của phương pháp nêu trên với các bước của phương pháp Kuhn-Munkres ở mục trước.
12.6. Nâng cấp
Dựa vào mô hình cài đặt thuật toán Kuhn-Munkres ở trên, ta có thể đánh giá về độ phức tạp tính toán lý thuyết của cách cài đặt này:
Thuật toán tìm kiếm theo chiều rộng được sử dụng để tìm đường mở có độ phức tạp O(k2), mỗi lần xoay trọng số cạnh mất một chi phí thời gian cỡ O(k2). Vậy mỗi lần tăng cặp, cần tối đa k lần dò đường và k lần xoay trọng số cạnh, mất một chi phí thời gian cỡ O(k3). Thuật toán cần k lần tăng cặp nên độ phức tạp tính toán trên lý thuyết của phương pháp này cỡ O(k4).
Có thể cải tiến mô hình cài đặt để được một thuật toán với độ phức tạp O(k3) dựa trên những nhậnxét sau:
12.6.1. Nhận xét 1
Quá trình tìm kiếm theo chiều rộng bắt đầu từ một đỉnh x* chưa ghép cho ta một cây pha gốc x*. Nếu tìm được đường mở thì dừng lại và tăng cặp ngay, nếu không thì xoay trọng số cạnh và bắt đầu tìm kiếm lại để được một cây pha mới lớn hơn cây pha cũ như hình dưới đây:
Cây pha "mọc" lớn hơn sau mỗi lần xoay trọng số cạnh và tìm đường
Nhận xét 2
Việc xác định trọng số nhỏ nhất của cạnh nối một X_đỉnh trong cây pha với một Y_đỉnh ngoài cây pha có thể kết hợp ngay trong bước dựng cây pha mà không làm tăng cấp phức tạp tính toán. Để thực hiện điều này, ta sử dụng kỹ thuật như trong thuật toán Prim:
Với mọi y∈Y, gọi d[y] := khoảng cách từ y đến cây pha gốc x* . Ban đầu d[y] được khởi tạo bằng trọng số cạnh (x* , y) = c[x* , y] - Fx[x*] - Fy[y] (cây pha ban đầu chỉ có đúng một đỉnh x*).
Trong bước tìm đường bằng BFS, mỗi lần rút một đỉnh x ra khỏi Queue, ta xét những đỉnh y∈Y chưa thăm và đặt lại d[y]mới := min(d[y]cũ, trọng số cạnh (x, y)) sau đó mới kiểm tra xem (x, y) có phải là 0_cạnh hay không để tiếp tục các thao tác như trước. Nếu quá trình BFS không tìm ra đường mở thì giá trị xoay ∆ chính là giá trị nhỏ nhất trong các d[y] dương. Ta bớt được một đoạn chương trình tìm giá trị xoay có độ phức tạp O(k2). Công việc tại mỗi bước xoay chỉ là tìm giá trị nhỏ nhất trong các d[y] dương và thực hiện phép cộng, trừ trên hai dãy đối ngẫu Fx và Fy, nó có độ phức tạp tính toán O(k), tối đa có k lần xoay để tìm đường mở nên tổng chi phí thời gian thực hiện các lần xoay cho tới khi tìm ra đường mở cỡ O(k2). Lưu ý rằng đồ thị đang xét là đồ thị hai phía đầy đủ nên sau khi xoay các trọng số cạnh bằng giá trị xoay ∆, tất cả các cạnh nối từ X_đỉnh trong cây pha tới Y_đỉnh ngoài cây pha đều bị giảm trọng số đi ∆, chính vì vậy ta phải trừ tất cả các d[y] > 0 đi ∆ để giữ được tính hợp lý của các d[y].
Nhận xét 3:
Ta có thể tận dụng kết quả của quá trình tìm kiếm theo chiều rộng ở bước trước để nới rộng cây pha cho bước sau (grow alternating tree) mà không phải tìm lại từ đầu (BFS lại bắt đầu từ x*).
Khi không tìm thấy đường mở, quá trình tìm kiếm theo chiều rộng sẽ đánh dấu được những đỉnh đã thăm (thuộc cây pha) và hàng đợi các X_đỉnh trong quá trình tìm kiếm trở thành rỗng. Tiếp theo là phải xác định được ∆ = trọng số nhỏ nhất của cạnh nối một X_đỉnh đã thăm với một Y_đỉnh chưa thăm và xoay các trọng số cạnh để những cạnh này trở thành 0_cạnh. Tại đây ta sẽ dùng kỹ thuật sau: Thăm luôn những đỉnh y∈Y chưa thăm tạo với một X_đỉnh đã thăm một 0_cạnh (những Y_đỉnh chưa thăm có d[y] = 0), nếu tìm thấy đường mở thì dừng ngay, nếu không thấy thì đẩy tiếp những đỉnh matchY[y] vào hàng đợi và lặp lại thuật toán tìm kiếm theo chiều rộng bắt đầu từ những đỉnh này. Vậy nếu xét tổng thể, mỗi lần tăng cặp ta chỉ thực hiện một lần dựng cây pha, tức là tổng chi phí thời gian của những lần thực hiện giải thuật tìm kiếm trên đồ thị sau mỗi lần tăng cặp chỉ còn là O(k2).
Nhận xét 4:
Thủ tục tăng cặp dựa trên đường mở (Enlarge) có độ phức tạp O(k)
Từ 3 nhận xét trên, phương pháp đối ngẫu Kuhn-Munkres có thể cài đặt bằng một chương trình có độ phức tạp tính toán O(k3) bởi nó cần k lần tăng cặp và chi phí cho mỗi lần là O(k2).
P_4_12_2.PAS * Cài đặt phương pháp Kuhn-Munkres O(n3) program AssignmentProblemSolve; const InputFile = 'ASSIGN.INP'; OutputFile = 'ASSIGN.OUT'; max = 100; maxC = 10001; var c: array[1..max, 1..max] of Integer; Fx, Fy, matchX, matchY: array[1..max] of Integer; Trace, Queue, d, arg: array[1..max] of Integer; first, last: Integer; start, finish: Integer; m, n, k: Integer; procedure Enter; {Nhập dữ liệu} var i, j: Integer; f: Text; begin Assign(f, InputFile); Reset(f); ReadLn(f, m, n); if m > n then k := m else k := n; for i := 1 to k do for j := 1 to k do c[i, j] := maxC; while not SeekEof(f) do ReadLn(f, i, j, c[i, j]); Close(f); end; procedure Init; {Khởi tạo bộ ghép rỗng và hai dãy đối ngẫu Fx, Fy} var i, j: Integer; begin FillChar(matchX, SizeOf(matchX), 0); FillChar(matchY, SizeOf(matchY), 0); for i := 1 to k do begin Fx[i] := maxC; for j := 1 to k do if c[i, j] < Fx[i] then Fx[i] := c[i, j]; end; for j := 1 to k do begin Fy[j] := maxC; for i := 1 to k do if c[i, j] - Fx[i] < Fy[j] then Fy[j] := c[i, j] - Fx[i]; end; end; function GetC(i, j: Integer): Integer; {Hàm trả về trọng số cạnh (X[i], Y[j])} begin GetC := c[i, j] - Fx[i] - Fy[j]; end; procedure InitBFS; {Thủ tục khởi tạo trước khi tìm cách ghép start∈X} var y: Integer; begin {Hàng đợi chỉ gồm mỗi một đỉnh Start ⇔ cây pha khởi tạo chỉ có 1 đỉnh start} first := 1; last := 1; Queue[1] := start; {Khởi tạo các Y_đỉnh đều chưa thăm ⇔ Trace[y] = 0, ∀y} FillChar(Trace, SizeOf(Trace), 0); {Khởi tạo các d[y]} for y := 1 to k do begin d[y] := GetC(start, y); {d[y] là khoảng cách từ y tới cây pha gốc start} arg[y] := start; {arg[y] là X_đỉnh thuộc cây pha tạo ra khoảng cách đó} end; finish := 0; end; procedure Push(v: Integer); {Đẩy một đỉnh v∈X vào hàng đợi} begin Inc(last); Queue[last] := v; end; function Pop: Integer; {Rút một X_đỉnh khỏi hàng đợi, trả về trong kết quả hàm} begin Pop := Queue[first]; Inc(first); end; procedure FindAugmentingPath; {Thủ tục tìm đường mở} var i, j, w: Integer; begin repeat i := Pop; {Rút một đỉnh X[i] khỏi hàng đợi} for j := 1 to k do {Quét những Y_đỉnh chưa thăm} if Trace[j] = 0 then begin w := GetC(i, j); {xét cạnh (X[i], Y[j])} if w = 0 then {Nếu là 0_cạnh} begin Trace[j] := i; {Lưu vết đường đi} if matchY[j] = 0 then {Nếu j chưa ghép thì ghi nhận nơi kết thúc đường mở và thoát} begin finish := j; Exit; end; Push(matchY[j]); {Nếu j đã ghép thì đẩy tiếp matchY[j] vào hàng đợi} end; if d[j] > w then {Cập nhật lại khoảng cách d[j] nếu thấy cạnh (X[i], Y[j]) ngắn hơn khoảng cách này} begin d[j] := w; arg[j] := i; end; end; until first > last; end; {Xoay các trọng số cạnh} procedure SubX_AddY; var Delta: Integer; x, y: Integer; begin {Trước hết tính ∆ = giá trị nhỏ nhất trọng số các d[y], với y∈Y chưa thăm (y không thuộc cây pha)} Delta := maxC; for y := 1 to k do if (Trace[y] = 0) and (d[y] < Delta) then Delta := d[y]; {Trừ trọng số những cạnh liên thuộc với start∈X đi ∆} Fx[start] := Fx[start] + Delta; for y := 1 to k do {Xét các đỉnh y∈Y} if Trace[y] <> 0 then {Nếu y thuộc cây pha} begin x := matchY[y]; {Thì x = matchY[y] cũng phải thuộc cây pha} Fy[y] := Fy[y] - Delta; {Cộng trọng số những cạnh liên thuộc với y lên ∆} Fx[x] := Fx[x] + Delta; {Trừ trọng số những cạnh liên thuộc với x đi ∆} end else d[y] := d[y] - Delta; {Nếu y ∉ cây pha thì sau bước xoay, khoảng cách từ y đến cây pha sẽ giảm ∆} {Chuẩn bị tiếp tụcBFS} for y := 1 to k do if (Trace[y] = 0) and (d[y] = 0) then {Thăm luôn những đỉnh y∈Y tạo với cây pha một 0_cạnh} begin Trace[y] := arg[y]; {Lưu vết đường đi} if matchY[y] = 0 then {Nếu y chưa ghép thì ghi nhận đỉnh kết thúc đường mở và thoát ngay} begin finish := y; Exit; end; Push(matchY[y]); {Nếu y đã ghép thì đẩy luôn matchY[y] vào hàng đợi để chờ loang tiếp} end; end; procedure Enlarge; {Nới rộng bộ ghép bằng đường mở kết thúc ở finish} var x, next: Integer; begin repeat x := Trace[finish]; next := matchX[x]; matchX[x] := finish; matchY[finish] := x; finish := Next; until finish = 0; end; procedure Solve; var x, y: Integer; begin for x := 1 to k do {Với mỗi X_đỉnh: } begin start := x; {Đặt nơi khởi đầu đường mở} InitBFS; {Khởi tạo cây pha} repeat FindAugmentingPath; {Tìm đường mở} if finish = 0 then SubX_AddY; {Nếu không thấy thì xoay các trọng số cạnh ...} until finish <> 0; {Cho tới khi tìm ra đường mở} Enlarge; {Nới rộng bộ ghép bởi đường mở tìm được} end; end; procedure Result; var x, y, Count, W: Integer; f: Text; begin Assign(f, OutputFile); Rewrite(f); WriteLn(f, 'Optimal assignment:'); W := 0; Count := 0; for x := 1 to m do {Với mỗi X_đỉnh, xét cặp ghép tương ứng} begin y := matchX[x]; if c[x, y] < maxC then {Chỉ quan tâm đến những cặp ghép có trọng số < maxC} begin Inc(Count); WriteLn(f, Count:5, ') X[', x, '] - Y[', y, '] ', c[x, y]); W := W + c[x, y]; end; end; WriteLn(f, 'Cost: ', W); Close(f); end; begin Enter; Init; Solve; Result; end.