Giải thuật và lập trình: §7. Chu trình Hamilton, đường đi Hamilton, đồ thị Hamilton

Các khóa học qua video:
Python SQL Server PHP C# Lập trình C Java HTML5-CSS3-JavaScript
Học trên YouTube <76K/tháng. Đăng ký Hội viên
Viết nhanh hơn - Học tốt hơn
Giải phóng thời gian, khai phóng năng lực

7.1. ĐỊNH NGHĨA

Cho đồ thị G = (V, E) có n đỉnh

Chu trình (x1, x2, ..., xn, x1) được gọi là chu trình Hamilton nếu xi ≠ xj với 1 ≤ i < j ≤ n

Đường đi (x1, x2, ..., xn) được gọi là đường đi Hamilton nếu xi ≠ xj với 1 ≤ i < j ≤ n

Có thể phát biểu một cách hình thức: Chu trình Hamilton là chu trình xuất phát từ 1 đỉnh, đi thăm tất cả những đỉnh còn lại mỗi đỉnh đúng 1 lần, cuối cùng quay trở lại đỉnh xuất phát. Đường đi Hamilton là đường đi qua tất cả các đỉnh của đồ thị, mỗi đỉnh đúng 1 lần. Khác với khái niệm chu trình Euler và đường đi Euler, một chu trình Hamilton không phải là đường đi Hamilton bởi có đỉnh xuất phát được thăm tới 2 lần.

Ví dụ: Xét 3 đơn đồ thị G1, G2, G3 như trong hình sau:

 

Đồ thị G1 có chu trình Hamilton (a, b, c, d, e, a). G2 không có chu trình Hamilton vì deg(a) = 1 nhưng có đường đi Hamilton (a, b, c, d). G3 không có cả chu trình Hamilton lẫn đường đi Hamilton.

7.2. Định lý

Đồ thị vô hướng G, trong đó tồn tại k đỉnh sao cho nếu xoá đi k đỉnh này cùng với những cạnh liên thuộc của chúng thì đồ thị nhận được sẽ có nhiều hơn k thành phần liên thông. Thì khẳng định là G không có chu trình Hamilton. Mệnh đề phản đảo của định lý này cho ta điều kiện cần để một đồ thị có chu trình Hamilton.

Định lý Dirac (1952): Đồ thị vô hướng G có n đỉnh (n ≥ 3). Khi đó nếu mọi đỉnh v của G đều có deg(v) ≥ n/2 thì G có chu trình Hamilton. Đây là một điều kiện đủ để một đồ thị có chu trình Hamilton.

Đồ thị có hướng G liên thông mạnh và có n đỉnh. Nếu deg+(v) ≥ n / 2 và deg-(v) ≥ n / 2 với mọi đỉnh v thì G có chu trình Hamilton.

7.3. Cài đặt

Dưới đây ta sẽ cài đặt một chương trình liệt kê tất cả các chu trình Hamilton xuất phát từ đỉnh 1, các chu trình Hamilton khác có thể có được bằng cách hoán vị vòng quanh. Lưu ý rằng cho tới nay, người ta vẫn chưa tìm ra một phương pháp nào thực sự hiệu quả hơn phương pháp quay lui để tìm dù chỉ một chu trình Hamilton cũng như đường đi Hamilton trong trường hợp đồ thị tổng quát.

Input: file văn bản HAMILTON.INP

• Dòng 1 ghi số đỉnh n (2 ≤ n ≤ 100) và số cạnh m của đồ thị cách nhau 1 dấu cách

• m dòng tiếp theo, mỗi dòng có dạng hai số nguyên dương u, v cách nhau 1 dấu cách, thể hiện u, v là hai đỉnh kề nhau trong đồ thị

Output: file văn bản HAMILTON.OUT liệt kê các chu trình Hamilton

 

P_4_07_1.PAS * Thuật toán quay lui liệt kê chu trình Hamilton

program All_of_Hamilton_Circuits;
const
  InputFile = 'HAMILTON.INP';
  OutputFile = 'HAMILTON.OUT';
  max = 100;
var
  fo: Text;
  a: array[1..max, 1..max] of Boolean; {Ma trận kề của đồ thị: a[u, v] = True (u, v) là cạnh}
  Free: array[1..max] of Boolean; {Mảng đánh dấu Free[v] = True nếu chưa đi qua đỉnh v}
  X: array[1..max] of Integer; {Chu trình Hamilton sẽ tìm là; 1=X[1]→X[2] → ... →X[n] →X[1]=1}
  n: Integer;

procedure Enter;
var
  i, u, v, m: Integer;
  f: Text;
begin
  Assign(f, InputFile);
  Reset(f);
  FillChar(a, SizeOf(a), False);
  ReadLn(f, n, m);
  for i := 1 to m do
  begin
    ReadLn(f, u, v);
    a[u, v] := True;
    a[v, u] := True;
  end;
  Close(f);
end;

procedure PrintResult; {In kết quả nếu tìm thấy chu trình Hamilton}
var
  i: Integer;
begin
  for i := 1 to n do Write(fo, X[i], ' ');
  WriteLn(fo, X[1]);
end;

procedure Try(i: Integer); {Thử các cách chọn đỉnh thứ i trong hành trình}
var
  j: Integer;
begin
  for j := 1 to n do {Đỉnh thứ i (X[i]) có thể chọn trong những đỉnh}
    if Free[j] and a[x[i - 1], j] then {kề với X[i - 1] và chưa bị đi qua }
    begin
      x[i] := j; {Thử một cách chọn X[i]}
      if i < n then {Nếu chưa thử chọn đến X[n]}
      begin
        Free[j] := False; {Đánh dấu đỉnh j là đã đi qua}
        Try(i + 1); {Để các bước thử kế tiếp không chọn phải đỉnh j nữa}
        Free[j] := True; {Sẽ thử phưng án khác cho X[i] nên sẽ bỏ đánh dấu đỉnh vừa thử}
      end;
      else {Nếu đã thử chọn đến X[n]}
        if a[j, X[1]] then PrintResult; {và nếu X[n] lại kề với X[1] thì ta có chu trình Hamilton}
    end;
  end;

begin
  Enter;
  FillChar(Free, SizeOf(Free), True); {Khởi tạo: Các đỉnh đều chưa đi qua}
  x[1] := 1; Free[1] := False; {Bắt đầu từ đỉnh 1}
  Assign(fo, OutputFile);
  Rewrite(fo);
  Try(2); {Thử các cách chọn đỉnh kế tiếp}
  Close(fo);
end.

Bài tập

Bài 1

a) Lập chương trình nhập vào một đồ thị và chỉ ra đúng một chu trình Hamilton nếu có.

b) Lập chương trình nhập vào một đồ thị và chỉ ra đúng một đường đi Hamilton nếu có.

Bài 2

Trong đám cưới của Péc-xây và An-đrơ-nét có 2n hiệp sỹ. Mỗi hiệp sỹ có không quá n - 1 kẻ thù.

Hãy giúp Ca-xi-ô-bê, mẹ của An-đrơ-nét xếp 2n hiệp sỹ ngồi quanh một bàn tròn sao cho không có hiệp sỹ nào phải ngồi cạnh kẻ thù của mình. Mỗi hiệp sỹ sẽ cho biết những kẻ thù của mình khi họ đến sân rồng.

Bài 3

Gray code: Một hình tròn được chia thành 2n hình quạt đồng tâm. Hãy xếp tất cả các xâu nhị phân độ dài n vào các hình quạt, mỗi xâu vào một hình quạt sao cho bất cứ hai xâu nào ở hai hình quạt cạnh nhau đều chỉ khác nhau đúng 1 bit. Ví dụ với n = 3:

Bài 4

Thách đố: Bài toán mã đi tuần: Trên bàn cờ tổng quát kích thước n x n ô vuông (n chẵn và 6 ≤ n ≤ 20). Trên một ô nào đó có đặt một quân mã. Quân mã đang ở ô (X1, Y1) có thể di chuyển sang ô (X2, Y2) nếu ⏐X1-X2⏐.⏐Y1-Y2⏐ = 2 (Xem hình vẽ).

Hãy tìm một hành trình của quân mã từ ô xuất phát, đi qua tất cả các ô của bàn cờ, mỗi ô đúng 1 lần.

Ví dụ:

Với n = 8, ô xuất phát (3, 3)

Với n = 10, ô xuất phát (6, 5)

Gợi ý: Nếu coi các ô của bàn cờ là các đỉnh của đồ thị và các cạnh là nối giữa hai đỉnh tương ứng với hai ô mã giao chân thì dễ thấy rằng hành trình của quân mã cần tìm sẽ là một đường đi Các thuật toán trên đồ thị Hamilton. Ta có thể xây dựng hành trình bằng thuật toán quay lui kết hợp với phương pháp duyệt ưu tiên Warnsdorff: Nếu gọi deg(x, y) là số ô kề với ô (x, y) và chưa đi qua (kề ở đây theo nghĩa đỉnh kề chứ không phải là ô kề cạnh) thì từ một ô ta sẽ không thử xét lần lượt các hướng đi có thể, mà ta sẽ ưu tiên thử hướng đi tới ô có deg nhỏ nhất trước. Trong trường hợp có tồn tại đường đi, phương pháp này hoạt động với tốc độ tuyệt vời: Với mọi n chẵn trong khoảng từ 6 tới 18, với mọi vị trí ô xuất phát, trung bình thời gian tính từ lúc bắt đầu tới lúc tìm ra một nghiệm < 1 giây.

 

Tuy nhiên trong trường hợp n lẻ, có lúc không tồn tại đường đi, do phải duyệt hết mọi khả năng nên thời gian thực thi lại hết sức tồi tệ. (Có xét ưu tiên như trên hay xét thứ tự như trước kia thì cũng vậy thôi. Ta có thể thử với n lẻ: 5, 7, 9 ... và ô xuất phát (1, 2), sau đó ngồi xem máy tính toát mồ hôi).

Nguồn: Giáo trình Giải thuật và Lập trình - Lê Minh Hoàng - Đại học sư phạm Hà Nội
» Tiếp: §8. Bài toán đường đi ngắn nhất
« Trước: §6. Chu trình Euler, đường đi Euler, đồ thị Euler
Các khóa học qua video:
Python SQL Server PHP C# Lập trình C Java HTML5-CSS3-JavaScript
Học trên YouTube <76K/tháng. Đăng ký Hội viên
Viết nhanh hơn - Học tốt hơn
Giải phóng thời gian, khai phóng năng lực
Copied !!!