Giải thuật và lập trình: §3.3. Biến đổi xâu

Các khóa học qua video:
Python SQL Server PHP C# Lập trình C Java HTML5-CSS3-JavaScript
Học trên YouTube <76K/tháng. Đăng ký Hội viên
Viết nhanh hơn - Học tốt hơn
Giải phóng thời gian, khai phóng năng lực

Cho xâu ký tự X, xét 3 phép biến đổi:

  1. Insert(i, C): i là số, C là ký tự: Phép Insert chèn ký tự C vào sau vị trí i của xâu X.
  2. Replace(i, C): i là số, C là ký tự: Phép Replace thay ký tự tại vị trí i của xâu X bởi ký tự C.
  3. Delete(i): i là số, Phép Delete xoá ký tự tại vị trí i của xâu X.

Yêu cầu: Cho trước xâu Y, hãy tìm một số ít nhất các phép biến đổi trên để biến xâu X thành xâu Y.

Input: file văn bản STR.INP

Dòng 1: Chứa xâu X (độ dài <= 100)

Dòng 2: Chứa xâu Y (độ dài <= 100)

Output: file văn bản STR.OUT ghi các phép biến đổi cần thực hiện và xâu X tại mỗi phép biến đổi.

STR.INP

STR.OUT

PBBCEFATZQABCDABEFA

7

PBBCEFATZ -> Delete(9) -> PBBCEFAT

PBBCEFAT -> Delete(8) -> PBBCEFA

PBBCEFA -> Insert(4, B) -> PBBCBEFA

PBBCBEFA -> Insert(4, A) -> PBBCABEFA

PBBCABEFA -> Insert(4, D) -> PBBCDABEFA

PBBCDABEFA -> Replace(2, A) -> PABCDABEFA

PABCDABEFA -> Replace(1, Q) -> QABCDABEFA

Cách giải:

Đối với xâu ký tự thì việc xoá, chèn sẽ làm cho các phần tử phía sau vị trí biến đổi bị đánh chỉ số lại, gây khó khăn cho việc quản lý vị trí. Để khắc phục điều này, ta sẽ tìm một thứ tự biến đổi thoả mãn: Phép biến đổi tại vị trí i bắt buộc phải thực hiện sau các phép biến đổi tại vị trí i + 1, i + 2, …

Ví dụ: X = 'ABCD';

Insert(0, E) sau đó Delete(4) cho ra X = 'EABD'. Cách này không tuân thủ nguyên tắc Delete(3) sau đó Insert(0, E) cho ra X = 'EABD'. Cách này tuân thủ nguyên tắc đề ra. Nói tóm lại ta sẽ tìm một dãy biến đổi có vị trí thực hiện giảm dần.

3.3.1. Công thức truy hồi

Giả sử m là độ dài xâu X và n là độ dài xâu Y. Gọi F[i, j] là số phép biến đổi tối thiểu để biến xâu gồm i ký tự đầu của xâu X: X1X2 … Xi thành xâu gồm j ký tự đầu của xâu Y: Y1Y2…Yj. Quan sát hai dãy X và Y.

Ta nhận thấy:

Nếu Xm = Yn thì ta chỉ cần biến đoạn X1X2…Xm-1 thành Y1Y2…Yn-1

Tức là trong trường hợp này: F[m, n] = F[m - 1, n - 1]

Nếu Xm khác Yn thì tại vị trí Xm ta có thể sử dụng một trong 3 phép biến đổi:

a) Hoặc chèn vào sau vị trí m của X, một ký tự đúng bằng Yn:

Thì khi đó F[m, n] sẽ bằng 1 phép chèn vừa rồi cộng với số phép biến đổi biến dãy X1…Xm thành dãy Y1…Yn-1: F[m, n] = 1 + F[m, n - 1]

b) Hoặc thay vị trí m của X bằng một ký tự đúng bằng Yn:

Thì khi đó F[m, n] sẽ bằng 1 phép thay vừa rồi cộng với số phép biến đổi biến dãy X1…Xm-1 thành dãy Y1…Yn-1: F[m, n] = 1 + F[m-1, n - 1]

c) Hoặc xoá vị trí thứ m của X:

Thì khi đó F[m, n] sẽ bằng 1 phép xoá vừa rồi cộng với số phép biến đổi biến dãy X1…Xm-1 thành dãy Y1…Yn: F[m, n] = 1 + F[m-1, n]

Vì F[m, n] phải là nhỏ nhất có thể, nên trong trường hợp Xm khác Yn thì F[m, n] = min(F[m, n - 1], F[m - 1, n - 1], F[m - 1, n]) + 1.

=> Ta xây dựng xong công thức truy hồi.

3.3.2. Cơ sở quy hoạch động

F[0, j] là số phép biến đổi biến xâu rỗng thành xâu gồm j ký tự đầu của F. Nó cần tối thiểu j phép chèn: F[0, j] = j

F[i, 0] là số phép biến đổi biến xâu gồm i ký tự đầu của S thành xâu rỗng, nó cần tối thiểu i phép xoá: F[i, 0] = i

Vậy đầu tiên bảng phương án F (cỡ [0..m, 0..n]) được khởi tạo hàng 0 và cột 0 là cơ sở quy hoạch động. Từ đó dùng công thức truy hồi tính ra tất cả các phần tử bảng B.

Sau khi tính xong thì F[m, n] cho ta biết số phép biến đổi tối thiểu.

Truy vết:

Nếu Xm = Yn thì chỉ việc xét tiếp F[m - 1, n - 1]. Nếu không, xét 3 trường hợp:

Nếu F[m, n] = F[m, n - 1] + 1 thì phép biến đổi đầu tiên được sử dụng là: Insert(m, Yn)

Nếu F[m, n] = F[m - 1, n - 1] + 1 thì phép biến đổi đầu tiên được sử dụng là: Replace(m, Yn) Nếu F[m, n] = F[m - 1, n] + 1 thì phép biến đổi đầu tiên được sử dụng là: Delete(m)

Đưa về bài toán với m, n nhỏ hơn truy vết tiếp cho tới khi về F[0, 0]

Ví dụ: X =' ABCD'; Y = 'EABD' bảng phương án là:

Lưu ý: khi truy vết, để tránh truy nhập ra ngoài bảng, nên tạo viền cho bảng.

P_3_03_4.PAS * Biến đổi xâu

program StrOpt;

const
  InputFile = 'STR.INP';
  OutputFile = 'STR.OUT';
  max = 100;

var
  X, Y: String[2 * max];
  F: array[-1..max, -1..max] of Integer;
  m, n: Integer;

procedure Enter;
  var
    fi: Text;
  
  begin
    Assign(fi, InputFile);
    Reset(fi);
    ReadLn(fi, X);
    ReadLn(fi, Y);
    Close(fi);
    m := Length(X);
    n := Length(Y);
  end;
  
function Min3(x, y, z: Integer): Integer; {Cho giá trị nhỏ nhất trong 3 giá trị x, y, z}
  var
    t: Integer;
  
  begin
    if x < y then t := x
    else t := y;
    if z < t then t := z;
    Min3 := t;
  end;

procedure Optimize;
  var
    i, j: Integer;
    
  begin {Khởi tạo viền cho bảng phương án}
    for i := 0 to m do F[i, -1] := max + 1;
    for j := 0 to n do F[-1, j] := max + 1;
    {Lưu cơ sở quy hoạch động}
    for j := 0 to n do F[0, j] := j;
    for i := 1 to m do F[i, 0] := i;
    {Dùng công thức truy hồi tính toàn bảng phương án}
    for i := 1 to m do for j := 1 to n do
      if X[i] = Y[j] then F[i, j] := F[i - 1, j - 1]
      else F[i, j] := Min3(F[i, j - 1], F[i - 1, j - 1], F[i - 1, j]) + 1;
  end;

procedure Trace; {Truy vết}
  var
    fo: Text;
  
  begin
    Assign(fo, OutputFile);
    Rewrite(fo);
    WriteLn(fo, F[m, n]); {F[m, n] chính là số ít nhất các phép biến đổi cần thực hiện}
    while (m <> 0) or (n <> 0) do {Vòng lặp kết thúc khi m = n = 0}
      if X[m] = Y[n] then {Hai ký tự cuối của 2 xâu giống nhau}
        begin
          Dec(m); Dec(n); {Chỉ việc truy chéo lên trên bảng phương án}
        end
      else {Tại đây cần một phép biến đổi}
        begin
          Write(fo, X, ' -> '); {In ra xâu X trước khi biến đổi}
          if F[m, n] = F[m, n - 1] + 1 then {Nếu đây là phép chèn}
            begin
              Write(fo, 'Insert(', m, ', ', Y[n], ')');
              Insert(Y[n], X, m + 1);
              Dec(n); {Truy sang phải}
            end
          else if F[m, n] = F[m - 1, n - 1] + 1 then {Nếu đây là phép thay}
            begin
              Write(fo, 'Replace(', m, ', ', Y[n], ')');
              X[m] := Y[n];
              Dec(m);
              Dec(n); {Truy chéo lên trên}
            end
          else {Nếu đây là phép xoá}
            begin
              Write(fo, 'Delete(', m, ')');
              Delete(X, m, 1);
              Dec(m); {Truy lên trên}
            end;
          WriteLn(fo, ' -> ', X); {In ra xâu X sau phép biến đổi}
        end;
    Close(fo);
  end;

begin
  Enter;
  Optimize;
  Trace;
end.

Bài này giải với các xâu <= 100 ký tự, nếu lưu bảng phương án dưới dạng mảng cấp phát động thì có thể làm với các xâu 255 ký tự. (Tốt hơn nên lưu mỗi dòng của bảng phương án là một mảng cấp phát động 1 chiều). Hãy tự giải thích tại sao khi giới hạn độ dài dữ liệu là 100, lại phải khai báo X và Y là String[200] chứ không phải là String[100] ?.

Nguồn: Giáo trình Giải thuật và Lập trình - Lê Minh Hoàng - Đại học sư phạm Hà Nội
» Tiếp: §3.4. Dãy con có tổng chia hết cho K
« Trước: §3.2. Bài toán cái túi
Các khóa học qua video:
Python SQL Server PHP C# Lập trình C Java HTML5-CSS3-JavaScript
Học trên YouTube <76K/tháng. Đăng ký Hội viên
Viết nhanh hơn - Học tốt hơn
Giải phóng thời gian, khai phóng năng lực
Copied !!!