Giải thuật và lập trình: §4. Kỹ thuật nhánh cận

Các khóa học qua video:
Python SQL Server PHP C# Lập trình C Java HTML5-CSS3-JavaScript
Học trên YouTube <76K/tháng. Đăng ký Hội viên
Viết nhanh hơn - Học tốt hơn
Giải phóng thời gian, khai phóng năng lực

BÀI TOÁN TỐI ƯU

Một trong những bài toán đặt ra trong thực tế là việc tìm ra một nghiệm thoả mãn một số điều kiện nào đó, và nghiệm đó là tốt nhất theo một chỉ tiêu cụ thể, nghiên cứu lời giải các lớp bài toán tối ưu thuộc về lĩnh vực quy hoạch toán học. Tuy nhiên cũng cần phải nói rằng trong nhiều trường hợp chúng ta chưa thể xây dựng một thuật toán nào thực sự hữu hiệu để giải bài toán, mà cho tới nay việc tìm nghiệm của chúng vẫn phải dựa trên mô hình liệt kê toàn bộ các cấu hình có thể và đánh giá, tìm ra cấu hình tốt nhất. Việc liệt kê cấu hình có thể cài đặt bằng các phương pháp liệt kê: Sinh tuần tự và tìm kiếm quay lui. Dưới đây ta sẽ tìm hiểu phương pháp liệt kê bằng thuật toán quay lui để tìm nghiệm của bài toán tối ưu.

SỰ BÙNG NỔ TỔ HỢP

Mô hình thuật toán quay lui là tìm kiếm trên 1 cây phân cấp. Nếu giả thiết rằng ứng với mỗi nút tương ứng với một giá trị được chọn cho xi sẽ ứng với chỉ 2 nút tương ứng với 2 giá trị mà xi+1 có  thể nhận thì cây n cấp sẽ có tới 2n nút lá, con số này lớn hơn rất nhiều lần so với dữ liệu đầu vào n. Chính vì vậy mà nếu như ta có thao tác thừa trong việc chọn xi thì sẽ phải trả giá rất lớn về chi phí thực thi thuật toán bởi quá trình tìm kiếm lòng vòng vô nghĩa trong các bước chọn kế tiếp xi+1, xi+2, … Khi đó, một vấn đề đặt ra là trong quá trình liệt kê lời giải ta cần tận dụng những thông tin đã tìm được để loại bỏ sớm những phương án chắc chắn không phải tối ưu. Kỹ thuật đó gọi là kỹ thuật đánh giá nhánh cận trong tiến trình quay lui.

MÔ HÌNH KỸ THUẬT NHÁNH CẬN

Dựa trên mô hình thuật toán quay lui, ta xây dựng mô hình sau:

procedure Init;

begin

<Khởi tạo một cấu hình bất kỳ BESTCONFIG>;

end;

{Thủ tục này thử chọn cho xi tất cả các giá trị nó có thể nhận}

procedure Try(i: Integer);

begin

for (Mọi giá trị V có thể gán cho xi) do begin

<Thử cho xi := V>;

if (Việc thử trên vẫn còn hi vọng tìm ra cấu hình tốt hơn BESTCONFIG) then

if (xi là phần tử cuối cùng trong cấu hình) then

<Cập nhật BESTCONFIG>

else

begin

<Ghi nhận việc thử xi = V nếu cần>;

Try(i + 1); {Gọi đệ quy, chọn tiếp xi+1 }

<Bỏ ghi nhận việc thử cho xi = V (nếu cần)>;

end;

end;

end;

begin

Init;

Try(1);

<Thông báo cấu hình tối ưu BESTCONFIG>

end.

Kỹ thuật nhánh cận thêm vào cho thuật toán quay lui khả năng đánh giá theo từng bước, nếu tại bước thứ i, giá trị thử gán cho xi không có hi vọng tìm thấy cấu hình tốt hơn cấu hình BESTCONFIG thì thử giá trị khác ngay mà không cần phải gọi đệ quy tìm tiếp hay ghi nhận kết  quả làm gì. Nghiệm của bài toán sẽ được làm tốt dần, bởi khi tìm ra một cấu hình mới (tốt hơn BESTCONFIG - tất nhiên), ta không in kết quả ngay mà sẽ cập nhật BESTCONFIG bằng cấu hình mới vừa tìm được.

BÀI TOÁN NGƯỜI DU LỊCH

Bài toán

Cho n thành phố đánh số từ 1 đến n và m tuyến đường giao thông hai chiều giữa chúng, mạng lưới giao thông này được cho bởi bảng C cấp nxn, ở đây Cij = Cji = Chi phí đi đoạn đường trực tiếp từ thành phố i đến thành phố j. Giả thiết rằng Cii = 0 với mọi i, Cij = +∞ nếu không có đường trực tiếp từ thành phố i đến thành phố j.

Một người du lịch xuất phát từ thành phố 1, muốn đi thăm tất cả các thành phố còn lại mỗi thành phố đúng 1 lần và cuối cùng quay lại thành phố 1. Hãy chỉ ra cho người đó hành trình với chi phí ít nhất. Bài toán đó gọi là bài toán người du lịch hay bài toán hành trình của một thương gia (Traveling Salesman).

Cách giải

Hành trình cần tìm có dạng (x1 = 1, x2, …, xn, xn+1 = 1) ở đây giữa xi và xi+1: hai thành phố liên tiếp trong hành trình phải có đường đi trực tiếp (Cij ≠ +∞) và ngoại trừ thành phố 1, không thành phố  nào được lặp lại hai lần. Có nghĩa là dãy (x1, x2, …, xn) lập thành 1 hoán vị của (1, 2, …, n).

Duyệt quay lui: x2 có thể chọn một trong các thành phố mà x1 có đường đi tới (trực tiếp), với mỗi cách thử chọn x2 như vậy thì x3 có thể chọn một trong các thành phố mà x2 có đường đi tới (ngoài x1). Tổng quát: xi có thể chọn 1 trong các thành phố chưa đi qua từ xi-1 có đường đi trực tiếp tới (1 i n).

Nhánh cận: Khởi tạo cấu hình BestConfig có chi phí = +∞. Với mỗi bước thử chọn xi xem chi phí đường đi cho tới lúc đó có < Chi phí của cấu hình BestConfig?, nếu không nhỏ hơn thì thử giá trị khác ngay bởi có đi tiếp cũng chỉ tốn thêm. Khi thử được một giá trị xn ta kiểm tra xem xn có đường đi trực tiếp về 1 không ? Nếu có đánh giá chi phí đi từ thành phố 1 đến thành phố xn cộng với chi phí từ xn đi trực tiếp về 1, nếu nhỏ hơn chi phí của đường đi BestConfig thì cập nhật lại BestConfig bằng cách đi mới.

Sau thủ tục tìm kiếm quay lui mà chi phí của BestConfig vẫn bằng +∞ thì có nghĩa là nó không tìm thấy một hành trình nào thoả mãn điều kiện đề bài để cập nhật BestConfig, bài toán không có lời giải, còn nếu chi phí của BestConfig < +∞ thì in ra cấu hình BestConfig - đó là hành trình ít tốn  kém nhất tìm được.

Input: file văn bản TOURISM.INP

  • Dòng 1: Chứa số thành phố n (1 ≤ n ≤ 20) và số tuyến đường m trong mạng lưới giao thông.

  • m dòng tiếp theo, mỗi dòng ghi số hiệu hai thành phố có đường đi trực tiếp và chi phí đi trên quãng đường đó (chi phí này là số nguyên dương ≤ 100).

Output: file văn bản TOURISM.OUT, ghi hành trình tìm được.

http://v1study.com/public/images/article/giai-thuat-va-lap-trinh-thuat-toan-tim-duong.png

Thuật toán:

P_1_04_1.PAS * Kỹ thuật nhánh cận dùng cho bài toán người du lịch

program TravellingSalesman;

const

InputFile = 'TOURISM.INP';

OutputFile = 'TOURISM.OUT';

max = 20;

maxC = 20 * 100 + 1;{+∞}

var

C: array[1..max, 1..max] of Integer; {Ma trận chi phí}

X, BestWay: array[1..max + 1] of Integer; {X để thử các khả năng, BestWay để ghi nhận nghiệm}

T: array[1..max + 1] of Integer; {Ti để lưu chi phí đi từ X1 đến Xi}

Free: array[1..max] of Boolean; {Free để đánh dấu, Freei= True nếu chưa đi qua tp i}

m, n: Integer;

MinSpending: Integer; {Chi phí hành trình tối ưu}

procedure Enter;

var

i, j, k: Integer;

f: Text;

begin

Assign(f, InputFile); Reset(f);

ReadLn(f, n, m);

for i := 1 to n do {Khởi tạo bảng chi phí ban đầu}

for j := 1 to n do

if i = j then C[i, j] := 0 else C[i, j] := maxC;

for k := 1 to m do

begin

ReadLn(f, i, j, C[i, j]);

C[j, i] := C[i, j]; {Chi phí như nhau trên 2 chiều}

end;

Close(f);

end;

procedure Init; {Khởi tạo}

begin

FillChar(Free, n, True);

Free[1] := False; {Các thành phố là chưa đi qua ngoại trừ thành phố 1}

X[1] := 1; {Xuất phát từ thành phố 1}

T[1] := 0; {Chi phí tại thành phố xuất phát là 0}

MinSpending := maxC;

end;

procedure Try(i: Integer); {Thử các cách chọn xi}

var

j: Integer;

begin

for j := 2 to n do {Thử các thành phố từ 2 đến n}

if Free[j] then {Nếu gặp thành phố chưa đi qua}

begin

X[i] := j; {Thử đi}

T[i] := T[i - 1] + C[x[i - 1], j]; {Chi phí := Chi phí bước trước + chi phí đường đi trực tiếp}

if T[i] < MinSpending then {Hiển nhiên nếu có điều này thì C[x[i - 1], j] < +∞ rồi}

if i < n then {Nếu chưa đến được xn}

begin

Free[j] := False; {Đánh dấu thành phố vừa thử}

Try(i + 1); {Tìm các khả năng chọn xi+1}

Free[j] := True; {Bỏ đánh dấu}

end

else

if T[n] + C[x[n], 1] < MinSpending then {Từ xn quay lại 1 vẫn tốn chi phí ít hơn trước}

begin {Cập nhật BestConfig}

BestWay := X;

MinSpending := T[n] + C[x[n], 1];

end;

end;

end;

procedure PrintResult;

var

i: Integer;

f: Text;

begin

Assign(f, OutputFile); Rewrite(f);

if MinSpending = maxC then WriteLn(f, 'NO SOLUTION')

else

for i := 1 to n do Write(f, BestWay[i], '->');

WriteLn(f, 1);

WriteLn(f, 'Cost: ', MinSpending);

Close(f);

end;

begin

Enter;

Init;

Try(2);

PrintResult;

end.

Trên đây là một giải pháp nhánh cận còn rất thô sơ giải bài toán người du lịch, trên thực tế người ta còn có nhiều cách đánh giá nhánh cận chặt hơn nữa. Hãy tham khảo các tài liệu khác để tìm hiểu về những phương pháp đó.

DÃY ABC

Cho trước một số nguyên dương N (N ≤ 100), hãy tìm một xâu chỉ gồm các ký tự A, B, C thoả mãn 3 điều kiện:

- Có độ dài N.

- Hai đoạn con bất kỳ liền nhau đều khác nhau (đoạn con là một dãy ký tự liên tiếp của xâu).

- Có ít ký tự C nhất.

Cách giải:

Không trình bày, đề nghị tự xem chương trình để hiểu, chỉ chú thích kỹ thuật nhánh cận như sau: Nếu dãy X1X2…Xn thoả mãn 2 đoạn con bất kỳ liền nhau đều khác nhau, thì trong 4 ký tự liên tiếp bất kỳ bao giờ cũng phải có 1 ký tự "C". Như vậy với một dãy con gồm k ký tự liên tiếp của dãy X thì số ký tự C trong dãy con đó bắt buộc phải ≥ k div 4.

Tại bước thử chọn Xi, nếu ta đã có Ti ký tự "C" trong đoạn đã chọn từ X1 đến Xi, thì cho dù các  bước đệ quy tiếp sau làm tốt như thế nào chăng nữa, số ký tự "C" sẽ phải chọn thêm bao giờ cũng ≥ (n - i) div 4. Tức là nếu theo phương án chọn Xi như thế này thì số ký tự "C" trong dãy kết quả (khi chọn đến Xn) cho dù có làm tốt đến đâu cũng ≥ Ti + (n - i) div 4. Ta dùng con số này để đánh giá nhánh cận, nếu nó nhiều hơn số ký tự "C" trong BestConfig thì chắc chắn có làm tiếp cũng chỉ được một cấu hình tồi tệ hơn, ta bỏ qua ngay cách chọn này và thử phương án khác.

Input: file văn bản ABC.INP chứa số nguyên dương n ≤ 100.

Output: file văn bản ABC.OUT ghi xâu tìm được.

ABC.INP

ABC.OUT

10

ABACABCBAB

"C" Letter Count : 2

Giải thuật:

P_1_04_2.PAS * Dãy ABC

program ABC_STRING;

const

InputFile = 'ABC.INP';

OutputFile = 'ABC.OUT';

max = 100;

var

N, MinC: Integer;

X, Best: array[1..max] of 'A'..'C';

T: array[0..max] of Integer; {Ti cho biết số ký tự "C" trong đoạn từ X1 đến Xi}

f: Text;

{Hàm Same(i, l) cho biết xâu gồm l ký tự kết thúc tại Xi có trùng với xâu l ký tự liền trước nó không ?}

function Same(i, l: Integer): Boolean;

var

j, k: Integer;

begin

j := i - l; {j là vị trí cuối đoạn liền trước đoạn đó}

for k := 0 to l - 1 do

if X[i - k] <> X[j - k] then begin

Same := False;

Exit;

end;

Same := True;

end;

{Hàm Check(i) cho biết Xi có làm hỏng tính không lặp của dãy X1X2 … Xi hay không}

function Check(i: Integer): Boolean;

var

l: Integer;

begin

for l := 1 to i div 2 do {Thử các độ dài l}

if Same(i, l) then {Nếu có xâu độ dài l kết thúc bởi Xi bị trùng với xâu liền trước}

begin

Check := False;

Exit;

end;

Check := True;

end;

{Giữ lại kết quả vừa tìm được vào BestConfig (MinC và mảng Best)}

procedure KeepResult;

begin

MinC := T[N];

Best := X;

end;

{Thuật toán quay lui có nhánh cận}

procedure Try(i: Integer); {Thử các giá trị có thể của Xi}

var

j: 'A'..'C';

begin

for j := 'A' to 'C' do {Xét tất cả các giá trị}

begin

X[i] := j;

if Check(i) then {Nếu thêm giá trị đó vào không làm hỏng tính không lặp }

begin

if j = 'C' then T[i] := T[i - 1] + 1 {Tính Ti qua Ti - 1}

else T[i] := T[i - 1];

if T[i] + (N - i) div 4 < MinC then {Đánh giá nhánh cận}

if i = N then KeepResult else Try(i + 1);

end;

end;

end;

procedure PrintResult;

var

i: Integer; begin

for i := 1 to N do Write(f, Best[i]); WriteLn(f);

WriteLn(f, '"C" Letter Count : ', MinC);

end;

begin

Assign(f, InputFile); Reset(f);

ReadLn(f, N);

Close(f);

Assign(f, OutputFile); Rewrite(f);

T[0] := 0;

MinC := N; {Khởi tạo cấu hình BestConfig ban đầu rất tồi}

Try(1);

PrintResult;

Close(f);

end.

Nếu ta thay bài toán là tìm xâu ít ký tự 'B' nhất mà vẫn viết chương trình tương tự như trên thì chương trình sẽ chạy chậm hơn chút ít. Lý do: thủ tục Try ở trên sẽ thử lần lượt các giá trị 'A', 'B', rồi mới đến 'C'. Có nghĩa ngay trong cách tìm, nó đã tiết kiệm sử dụng ký tự 'C' nhất nên trong phần lớn các bộ dữ liệu nó nhanh chóng tìm ra lời giải hơn so với bài toán tương ứng tìm xâu ít ký tự 'B' nhất. Chính vì vậy mà nếu như đề bài yêu cầu ít ký tự 'B' nhất ta cứ lập chương trình làm yêu cầu ít ký tự 'C' nhất, chỉ có điều khi in kết quả, ta đổi vai trò 'B', 'C' cho nhau. Đây là một ví dụ cho thấy sức mạnh của thuật toán quay lui khi kết hợp với kỹ thuật nhánh cận, nếu viết quay lui thuần tuý hoặc đánh giá nhánh cận không tốt thì với N = 100, tôi cũng không đủ kiên nhẫn để đợi chương trình cho kết quả (chỉ biết rằng > 3 giờ). Trong khi đó khi N = 100, với chương trình trên chỉ chạy hết hơn 3 giây cho kết quả là xâu 27 ký tự 'C'.

Nói chung, ít khi ta gặp bài toán mà chỉ cần sử dụng một thuật toán, một mô hình kỹ thuật cài đặt là có thể giải được. Thông thường các bài toán thực tế đòi hỏi phải có sự tổng hợp, pha trộn nhiều thuật toán, nhiều kỹ thuật mới có được một lời giải tốt. Không được lạm dụng một kỹ thuật nào và cũng không xem thường một phương pháp nào khi bắt tay vào giải một bài toán tin học. Thuật toán quay lui cũng không phải là ngoại lệ, ta phải biết phối hợp một cách uyển chuyển với các thuật toán khác thì khi đó nó mới thực sự là một công cụ mạnh.

Bài tập:

Bài 1

Một dãy dấu ngoặc hợp lệ là một dãy các ký tự "(" và ")" được định nghĩa như sau:

  1. Dãy rỗng là một dãy dấu ngoặc hợp lệ độ sâu 0

  2. Nếu A là dãy dấu ngoặc hợp lệ độ sâu k thì (A) là dãy dấu ngoặc hợp lệ độ sâu k + 1

  3. Nếu A và B là hay dãy dấu ngoặc hợp lệ với độ sâu lần lượt là p và q thì AB là dãy dấu ngoặc hợp lệ độ sâu là max(p, q)

Độ dài của một dãy ngoặc là tổng số ký tự "(" và ")"

Ví dụ: Có 5 dãy dấu ngoặc hợp lệ độ dài  8 và độ sâu 3:

1. ((()()))

2. ((())())

3. ((()))()

4. (()(()))

5. ()((()))

Bài toán đặt ra là khi cho biết trước hai số nguyên dương n và k. Hãy liệt kê hết các dãy ngoặc hợp lệ có độ dài là n và độ sâu là k (làm được với n càng lớn càng tốt).

Bài 2

Cho một bãi mìn kích thước mxn ô vuông, trên một ô có thể có chứa một quả mìn hoặc không, để biểu diễn bản đồ mìn đó, người ta có hai cách:

Cách 1: dùng bản đồ đánh dấu: sử dụng một lưới ô vuông kích thước mxn, trên đó tại ô (i, j) ghi số  1 nếu ô đó có mìn, ghi số 0 nếu ô đó không có mìn.

Cách 2: dùng bản đồ mật độ: sử dụng một lưới ô vuông kích thước mxn, trên đó tại ô (i, j) ghi một số trong khoảng từ 0 đến 8 cho biết tổng số mìn trong các ô lân cận với ô (i, j) (ô lân cận với ô (i, j) là ô có chung với ô (i, j) ít nhất 1 đỉnh).

Giả thiết rằng hai bản đồ được ghi chính xác theo tình trạng mìn trên hiện trường.

Về nguyên tắc, lúc cài bãi mìn phải vẽ cả bản đồ đánh dấu và bản đồ mật độ, tuy nhiên sau một thời gian dài, khi người ta muốn gỡ mìn ra khỏi bãi thì vấn đề hết sức khó khăn bởi bản đồ đánh dấu đã bị thất lạc !!. Công việc của các lập trình viên là: Từ bản đồ mật độ, hãy tái tạo lại bản đồ đánh dấu của bãi mìn.

Dữ liệu: Vào từ file văn bản MINE.INP, các số trên 1 dòng cách nhau ít nhất 1 dấu cách

  • Dòng 1: Ghi 2 số nguyên dương m, n (2 ≤ m, n ≤ 30)

  • m dòng tiếp theo, dòng thứ i ghi n số trên hàng i của bản đồ mật độ theo đúng thứ tự từ trái qua phải.

Kết quả: Ghi ra file văn bản MINE.OUT, các số trên 1 dòng ghi cách nhau ít nhất 1 dấu cách

  • Dòng 1: Ghi tổng số lượng mìn trong bãi

  • m dòng tiếp theo, dòng thứ i ghi n số trên hàng i của bản đồ đánh dấu theo đúng thứ tự từ  trái qua phải.

Ví dụ:

v1study.com/public/images/article/giai-thuat-lap-trinh-bai-toan-do-min.png

Nguồn: Giáo trình Giải thuật và Lập trình - Lê Minh Hoàng - Đại học sư phạm Hà Nội
« Trước: §3. Thuật toán quay lui
Các khóa học qua video:
Python SQL Server PHP C# Lập trình C Java HTML5-CSS3-JavaScript
Học trên YouTube <76K/tháng. Đăng ký Hội viên
Viết nhanh hơn - Học tốt hơn
Giải phóng thời gian, khai phóng năng lực
Copied !!!